SUMIFで複数条件を指定する方法｜AND・OR・期間で合計
※写真はイメージです
書き方
=SUMIFS(合計範囲, 範囲1, 条件1, 範囲2, 条件2)条件が2つ以上で「AかつB」なら SUMIFS、「AまたはB」なら SUMIF を足し算します。SUMIFSは合計範囲が先頭に来るので、SUMIFと順番が違います。
この図の表をExcelファイルでダウンロード（問題と答えのシートつき）
「AまたはB」で合計（OR条件）
期間（〇日から〇日まで）で合計
=SUMIFS(C2:C100,A2:A100,">="&DATE(2026,11,1),A2:A100,"<"&DATE(2026,12,1))日付の列に「以上」と「未満」の2つの条件をかけます。日付は ">=2026/11/1" と書くより、DATE関数か日付を入れたセルを & でつなぐほうが確実です。
「AまたはB」で、かつC
=SUM(SUMIFS(C2:C6,A2:A6,{"東京","大阪"},B2:B6,"11月"))東京か大阪で、11月の売上の合計（この例では 140）。ORの条件を { } に並べてSUMで足します。
うまくいかないとき
1#VALUE! になる
合計範囲と条件の範囲の行の数がそろっていません。
直し方すべての範囲を同じ行にします。
20になる
SUMIFの順番（範囲, 条件, 合計範囲）のままSUMIFSを書いています。
直し方SUMIFSは 合計範囲が先頭 です。
3日付の条件で0になる
日付が文字で入っているか、条件の書き方が文字になっています。
直し方日付の列が右寄せ（数値）か確かめ、条件は ">="&DATE(…) で書きます。
サンプルファイルで試す
「問題」のシートの黄色いセルに式を入れて、「答え」のシートと比べてください。
sumif-fukusu.xlsx をダウンロード（無料・登録なし）
よくある質問
条件はいくつまで指定できますか？
SUMIFSは範囲と条件の組を127組まで入れられます。
集計表を一気に作れますか？
縦に支店、横に月を並べた表を作り、<code>=SUMIFS($C$2:$C$6,$A$2:$A$6,$E2,$B$2:$B$6,F$1)</code> のように $ を付けてコピーします。毎回いろいろな切り口で見たいなら <a href="../pivot/">ピボットテーブル</a> が向いています。
Googleスプレッドシートでも同じですか？
はい。SUMIFS も { } の書き方も同じです。
一緒に覚えたい関数・操作
このページについて
操作の説明は Microsoft 365 の日本語版Excel（Windows）に合わせています。図はこのサイトで作ったもので、表の会社名・商品名・人名は架空です。運営者情報